default swf does not go away

[chefkeifer]

I have this code and i am trying to make when i click to make the default home.swf alpha 0. all functionality works just fine but when i click on my navigation buttons the default home.swf does not go away how do i fix this.

 

import com.greensock.*;  
import com.greensock.loading.*;  
import com.greensock.events.LoaderEvent;  
import com.greensock.loading.display.*;
import com.google.analytics.AnalyticsTracker; 
import com.google.analytics.GATracker;
//*****====================================================*****\\
var tracker:AnalyticsTracker = new GATracker( this, "UA-17893711-1", "AS3", false );
/*tracker.trackPageview("btn1"); tracker.trackPageview("btn2"); tracker.trackPageview("btn3");
tracker.trackPageview("btn4"); tracker.trackPageview("btn5"); tracker.trackPageview("btn6");
tracker.trackPageview("fr_palmetto"); tracker.trackPageview("fr_busco");
tracker.trackPageview("fr_broad");*/
//*****====================================================*****\\
var btns:Array = [home, schedule, parks, contact];
var swfs:Array = ["home.swf","schedule.swf","parks.swf","contact.swf"];
//*****====================================================*****\\
home.btn_txt.text = "HOME"
schedule.btn_txt.text = "SCHEDULE"
parks.btn_txt.text = "PARKS"
contact.btn_txt.text = "CONTACT"
//*****====================================================*****\\
var activeTween:TimelineLite;
var curLoader:SWFLoader;
var queue:LoaderMax = new LoaderMax({name:"mainQueue", onProgress:progressHandler, onComplete:completeHandler, onError:errorHandler}); 
LoaderMax.prioritize("home");
activeTween = null;
//*****==========================*****\\
for (var j:int = 0; j < btns.length; j++) {
  btns[j].buttonMode = true;
  btns[j].mouseChildren = false;
  btns[j].addEventListener(MouseEvent.ROLL_OVER, over);
  btns[j].addEventListener(MouseEvent.ROLL_OUT, out);
  btns[j].addEventListener(MouseEvent.CLICK, clickHandler);
  activeTween = new TimelineLite({paused:true});
  activeTween.insert(TweenMax.to(btns[j], .5, {glowFilter:{color:0xffffff, alpha:1, blurX:15, blurY:15, inner:true}}));
  activeTween.insert(TweenMax.to(btns[j], .5, {dropShadowFilter:{color:0x000000, alpha:1, blurX:5, blurY:5, distance:5}}));
  btns[j].tween = activeTween;
  btns[j].loader = new SWFLoader(swfs[j], {estimatedBytes:3000, container:this,x:0,y:315,alpha:0, autoPlay:false});
  queue.append( btns[j].loader );
}
//*****====================================================*****\\
queue.load();
//*****====================================================******//
function over(event:MouseEvent):void {
  activeTween = event.currentTarget.tween;
  activeTween.play();
}
//*****=====================*****\\
function out(event:MouseEvent):void {
  activeTween.reverse();
}
//*****====================================================*****\\
function progressHandler(event:LoaderEvent):void {  
trace("progress: " + event.target.progress);
}  
//*****====================================================******//  
function completeHandler(event:LoaderEvent):void {  
var image:ContentDisplay = LoaderMax.getContent("home.swf");  
	TweenLite.to(image, 1, {alpha:1});
	trace(event.target + " is complete!"); 

}  
//*****====================================================******//
function errorHandler(event:LoaderEvent):void {  
trace("error occured with " + event.target + ": " + event.text);  
}
//*****====================================================******//
function clickHandler(event:MouseEvent):void {
   if (curLoader != null) {
       TweenMax.to(curLoader.content, 0.5, {autoAlpha:0});

   }
   curLoader = event.currentTarget.loader;
   addChild(curLoader.content);
   TweenMax.to(curLoader.content, 0.5, {autoAlpha:1});
}

[GreenSock]

You never set the initial curLoader value to the loader associated with "home.swf". So when this code runs:

 

if (curLoader != null) {
       TweenMax.to(curLoader.content, 0.5, {autoAlpha:0});
}

 

It doesn't execute because curLoader is null initially. See what I mean?

[chefkeifer]

I guess i am not sure how to do that. do i need to something like this.

 

function completeHandler(event:LoaderEvent):void {  
var image:ContentDisplay = LoaderMax.getContent("home.swf");  
	TweenLite.to(image, 1, {alpha:1});
	trace(event.target + " is complete!"); 
                               curLoader == null;
} 

becuase that didnt do anything.

[GreenSock]

No, you need to set your curLoader initially to the "home.swf" SWFLoader. You could do it by putting this code after your loop:

 

curLoader = btns[0].loader;